{
  description = "Web Engineering";

  inputs = {
    flake-parts.url = "github:hercules-ci/flake-parts";
    nixpkgs.url = "github:NixOS/nixpkgs/9da7f1cf7f8a6e2a7cb3001b048546c92a8258b4";
  };

  outputs = inputs @ {
    flake-parts,
    self,
    ...
  }:
    flake-parts.lib.mkFlake {inherit inputs;} {
      imports = [];
      systems = ["x86_64-linux" "aarch64-linux" "aarch64-darwin" "x86_64-darwin"];
      perSystem = {
        config,
        self',
        inputs',
        pkgs,
        system,
        ...
      }:
        with pkgs.lib; let
          latexPackages = with pkgs; [
            latexrun
            (texlive.withPackages
              (ps:
                with ps; [
                  amsmath
                  biber
                  biblatex
                  changepage
                  csquotes
                  enumitem
                  fontaxes
                  latexmk
                  listings
                  minted
                  newtx
                  newtxsf
                  newtxtt
                  scheme-medium
                  textpos
                  times
                  titlesec
                  transparent
                  upquote
                ]))
          ];

          angularPackages = with pkgs; [
            nodePackages."@angular/cli"
          ];
        in {
          # Per-system attributes can be defined here. The self' and inputs'
          # module parameters provide easy access to attributes of the same
          # system.
          packages = with pkgs; let
            fmtNum = strings.fixedWidthNumber 2;
            fmtReleaseName = sem: author: chap: "${fmtNum sem} - ${fmtNum chap} - ${author.lastName}, ${author.firstName}.pdf";
            fmtRelease = fmtReleaseName 3 {
              firstName = "Linus";
              lastName = "Nagel";
            };
            mkUebungPdf = n: args:
              stdenvNoCC.mkDerivation rec {
                name = fmtRelease n;
                version = "1.0.0";
                src = ./.;
                buildInputs = latexPackages;
                buildPhase =
                  # sh
                  ''
                    cd docs/uebungen

                    latexmk \
                      -pdf \
                      -l -dir-report -file-line-error -verbose \
                      -interaction=nonstopmode \
                      "uebung-${toString n}.tex"
                  '';
                installPhase =
                  # sh
                  ''
                    mkdir -p $out/share $out/log $out/artifacts
                    cp out/uebung-${toString n}.pdf "$out/share/${name}"
                    cp out/*.log $out/log/
                    cp -r out/* $out/artifacts
                  '';
              }
              // args;
          in {
            "uebung-5" = mkUebungPdf 5 {};
            "uebung-6" = mkUebungPdf 6 {};
          };

          devShells.default = with pkgs;
            mkShell {
              nativeBuildInputs = [];
              packages =
                [
                  mermaid-cli
                  openjdk
                  jetty
                  maven
                ]
                ++ latexPackages
                ++ angularPackages;

              shellHook =
                # bash
                ''
                  # jetty docs: https://jetty.org/docs/jetty/12.1/operations-guide/begin/index.html
                  export JETTY_HOME="$(readlink -f .)/.jetty/home"
                  export JETTY_BASE="$(readlink -f .)/.jetty/base"

                  mkdir -p "$JETTY_HOME" "$JETTY_BASE"
                  for item in ${pkgs.jetty}/*; do
                      ln -sf "$item" "$JETTY_HOME/"
                  done

                  jetty() {
                    mkdir -p $JETTY_BASE/webapps/
                    ln -fs "$(readlink -f target/*.war)" $JETTY_BASE/webapps/

                    java \
                      -Djetty.home="$JETTY_HOME" \
                      -Djetty.base="$JETTY_BASE" \
                      -jar $JETTY_HOME/start.jar $@
                  }

                  jetty --add-modules=http,ee11-cdi,ee11-ext,ee11-deploy,ee11-environment,ee11-annotations,ee11-glassfish-jstl,ee11-jndi,ee11-jsp,ee11-jstl,ee11-plus,ee11-security,ee11-servlet,ee11-servlets,ee11-webapp,ee11-websocket-jakarta,ee11-websocket-jetty,ee11-websocket-jetty-client-webapp

                  echo "Usage Example:"
                  echo "mvn clean package # build demo.war"
                  echo "jetty # run webserver"
                '';
            };
        };
      flake = {
        # The usual flake attributes can be defined here, including system-
        # agnostic ones like nixosModule and system-enumerating ones, although
        # those are more easily expressed in perSystem.
      };
    };
}